Terraform

Dùng Terraform để cung cấp hạ tầng trên Linode

Cơ sở hạ tầng dưới dạng mã (IaC) là một phương pháp phát triển và vận hành cho phép triển khai máy chủ và cấu hình phần mềm được thể hiện dưới dạng mã. Phương pháp này làm giảm khả năng xảy ra lỗi của con người, giúp các hệ thống phức tạp dễ quản lý hơn, tạo điều kiện thuận lợi cho sự hợp tác trong các dự án kỹ thuật hệ thống và mang lại một số lợi ích khác.

Terraform là một công cụ IaC tập trung vào việc tạo, sửa đổi và hủy máy chủ, thay vì quản lý phần mềm trên các máy chủ đó. Terraform cung cấp các plugin để giao tiếp với các nhà cung cấp dịch vụ lưu trữ khác nhau và có sẵn plugin Linode chính thức . Hướng dẫn này sẽ chỉ cho bạn cách bắt đầu với Terraform và Linode.

Các Linode được tạo bằng Terraform có thể được cấu hình thêm bằng các hệ thống container như Docker hoặc bằng phần mềm quản lý cấu hình như Salt, Puppet, Ansible hoặc Chef.

Quan trọng: Cấu hình và lệnh được sử dụng trong hướng dẫn này dẫn đến việc nhiều Linode được thêm vào tài khoản của bạn. Hãy đảm bảo theo dõi chặt chẽ tài khoản của bạn trong Linode Manager để tránh các khoản phí không mong muốn.

Trước khi bạn bắt đầu

  • Hướng dẫn này chỉ cho bạn cách cài đặt và sử dụng phần mềm máy khách Terraform từ hệ thống Linux. Terraform có thể được cài đặt trên các hệ điều hành khác và hướng dẫn cho các nền tảng đó tương tự như các lệnh được trình bày trong hướng dẫn này.
  • Bạn cần mã thông báo truy cập cá nhân cho API v4 của Linode để sử dụng với Terraform. Làm theo hướng dẫn Bắt đầu với API Linode để nhận mã thông báo.

Ghi chú: Bất kỳ Mã thông báo truy cập cá nhân nào được tạo từ Linode Manager trước đó đều là mã thông báo API v3 và không hoạt động với nhà cung cấp Linode của Terraform.

Cài đặt Terraform

1.Để cài đặt phiên bản Terraform mới nhất trên nhiều bản phân phối Linux và macOS khác nhau, hãy sử dụng các lệnh sau:

Ubuntu/Debian :

wget -O- https://apt.releases.hashicorp.com/gpg | sudo gpg --dearmor -o /usr/share/keyrings/hashicorp-archive-keyring.gpg
echo "deb [signed-by=/usr/share/keyrings/hashicorp-archive-keyring.gpg] https://apt.releases.hashicorp.com $(lsb_release -cs) main" | sudo tee /etc/apt/sources.list.d/hashicorp.list
sudo apt update && sudo apt install terraform

CentOS/RHEL :

sudo yum install -y yum-utils
sudo yum-config-manager --add-repo https://rpm.releases.hashicorp.com/RHEL/hashicorp.repo
sudo yum -y install terraform

Fedora:

sudo dnf install -y dnf-plugins-core
sudo dnf config-manager --add-repo https://rpm.releases.hashicorp.com/fedora/hashicorp.repo
sudo dnf -y install terraform

macOS :

brew tap hashicorp/tap
brew install hashicorp/tap/terraform

2.Xác minh Terraform có thể chạy bằng cách chỉ cần gọi nó mà không có tùy chọn hoặc đối số:

terraform
Usage: terraform [-version] [-help] <command> [args]

The available commands for execution are listed below. The most common, useful commands are shown first, followed by less common or more advanced commands. If you're just getting started with Terraform, stick with the common commands. For the other commands, please read the help and docs before usage.

Common commands:
    apply              Builds or changes infrastructure
    console            Interactive console for Terraform interpolations
    destroy            Destroy Terraform-managed infrastructure
    env                Workspace management
    fmt                Rewrites config files to canonical format
    get                Download and install modules for the configuration
    graph              Create a visual graph of Terraform resources
    import             Import existing infrastructure into Terraform
    init               Initialize a Terraform working directory
    output             Read an output from a state file
    plan               Generate and show an execution plan
    providers          Prints a tree of the providers used in the configuration
    push               Upload this Terraform module to Atlas to run
    refresh            Update local state file against real resources
    show               Inspect Terraform state or plan
    taint              Manually mark a resource for recreation
    untaint            Manually unmark a resource as tainted
    validate           Validates the Terraform files
    version            Prints the Terraform version
    workspace          Workspace management

All other commands:
    debug              Debug output management (experimental)
    force-unlock       Manually unlock the terraform state
    state              Advanced state management

Xây dựng với Nhà cung cấp Linode

Terraform sử dụng phương pháp khai báo trong đó các tệp cấu hình chỉ định trạng thái kết thúc mong muốn của cơ sở hạ tầng, do đó các ví dụ trong hướng dẫn này sẽ chỉ liệt kê các Linode mà chúng ta muốn tạo. Terraform có thể hiểu hai loại tệp cấu hình: JSON và Ngôn ngữ cấu hình HashiCorp (HCL). Hướng dẫn này sử dụng định dạng HCL và các tệp HCL kết thúc bằng .tfphần mở rộng.

1.Tạo tệp linode-terraform-web.tftrong ~/terraformthư mục của bạn với đoạn mã bên dưới. Điền mã thông báo API Linode, khóa SSH công khai và mật khẩu gốc mong muốn vào nơi được chỉ định. Ngoài ra, hãy thay thế nhà cung cấp Linode versionthành mới nhất :

terraform {
  required_providers {
    linode = {
      source = "linode/linode"
      version = "2.5.2"
    }
  }
}

provider "linode" {
  token = "YOUR_LINODE_API_TOKEN"
}

resource "linode_instance" "terraform-web" {
        image = "linode/ubuntu18.04"
        label = "Terraform-Web-Example"
        group = "Terraform"
        region = "us-east"
        type = "g6-standard-1"
        authorized_keys = [ "YOUR_PUBLIC_SSH_KEY" ]
        root_pass = "YOUR_ROOT_PASSWORD"
}

Đoạn mã này tạo ra một Linode 2GB được gắn nhãn Terraform-Web-Exampletrong Terraformnhóm Linodes. Mặc dù phần mềm của máy chủ sẽ không được cấu hình trong hướng dẫn này, nhưng chúng ta có thể hình dung rằng Linode hoạt động như một máy chủ web.

2.Khởi tạo cấu hình Terraform:

terraform init

Terraform xác nhận khởi tạo thành công:

Initializing provider plugins...
- Checking for available provider plugins on https://releases.hashicorp.com...
- Downloading plugin for provider "linode" (1.0.0)...

The following providers do not have any version constraints in configuration,
so the latest version was installed.

To prevent automatic upgrades to new major versions that may contain breaking
changes, it is recommended to add version = "..." constraints to the
corresponding provider blocks in configuration, with the constraint strings
suggested below.

* provider.linode: version = "~> 1.0"
Terraform has been successfully initialized!

Ghi chú

Nếu xảy ra lỗi, hãy chạy lại lệnh ở chế độ gỡ lỗi:

TF_LOG=debug terraform init

3.Chạy lệnh plan của Terraform:

terraform plan
Refreshing Terraform state in-memory prior to plan...
The refreshed state will be used to calculate this plan, but will not be
persisted to local or remote state storage.


------------------------------------------------------------------------

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  + linode_instance.terraform-web
      id:                 <computed>
      alerts.#:           <computed>
      authorized_keys.#:  "1"
      authorized_keys.0:  "ssh-rsa ..."
      backups.#:          <computed>
      backups_enabled:    <computed>
      boot_config_label:  <computed>
      group:              "Terraform"
      image:              "linode/ubuntu18.04"
      ip_address:         <computed>
      ipv4.#:             <computed>
      ipv6:               <computed>
      label:              "web"
      private_ip_address: <computed>
      region:             "us-east"
      root_pass:          <sensitive>
      specs.#:            <computed>
      status:             <computed>
      swap_size:          <computed>
      type:               "g6-standard-1"
      watchdog_enabled:   "true"


Plan: 1 to add, 0 to change, 0 to destroy.

------------------------------------------------------------------------

Note: You didn't specify an "-out" parameter to save this plan, so Terraform
can't guarantee that exactly these actions will be performed if
"terraform apply" is subsequently run.

terraform plansẽ không thực hiện bất kỳ hành động nào hoặc thực hiện bất kỳ thay đổi nào trên tài khoản Linode của bạn. Thay vào đó, một phân tích được thực hiện để xác định hành động nào (tức là tạo, xóa hoặc sửa đổi phiên bản Linode) là cần thiết để đạt được trạng thái được mô tả trong cấu hình của bạn.

Ghi chú

Chế độ gỡ lỗi có thể được áp dụng cho lệnh plan nếu bạn cần thực hiện khắc phục sự cố:

TF_LOG=debug terraform plan

4.Nếu không có lỗi, hãy bắt đầu triển khai:

terraform apply

Bạn được yêu cầu xác nhận hành động. Nhập yesvà nhấn Enter :

Do you want to perform these actions?
  Terraform will perform the actions described above.
  Only 'yes' will be accepted to approve.

  Enter a value: yes

linode_instance.terraform-web: Creating...
  alerts.#:           "" => "<computed>"
  authorized_keys.#:  "" => "1"
  authorized_keys.0:  "" => "ssh-rsa ..."
  backups.#:          "" => "<computed>"
  backups_enabled:    "" => "<computed>"
  boot_config_label:  "" => "<computed>"
  group:              "" => "Terraform"
  image:              "" => "linode/ubuntu18.04"
  ip_address:         "" => "<computed>"
  ipv4.#:             "" => "<computed>"
  ipv6:               "" => "<computed>"
  label:              "" => "web"
  private_ip_address: "" => "<computed>"
  region:             "" => "us-east"
  root_pass:          "<sensitive>" => "<sensitive>"
  specs.#:            "" => "<computed>"
  status:             "" => "<computed>"
  swap_size:          "" => "<computed>"
  type:               "" => "g6-standard-1"
  watchdog_enabled:   "" => "true"
linode_instance.terraform-web: Still creating... (10s elapsed)
linode_instance.terraform-web: Still creating... (20s elapsed)
linode_instance.terraform-web: Still creating... (30s elapsed)
linode_instance.terraform-web: Still creating... (40s elapsed)
linode_instance.terraform-web: Still creating... (50s elapsed)
linode_instance.terraform-web: Creation complete after 52s (ID: 10975739)

Apply complete! Resources: 1 added, 0 changed, 0 destroyed.

5.Truy cập Trình quản lý Linode. Bạn sẽ thấy Linode Terraform-Web-Exampleđã được thêm vào tài khoản của bạn.

Cung cấp thêm máy chủ

Ở bước trước, bạn đã sử dụng Terraform để cung cấp một Linode có thể hoạt động như một máy chủ web. Để minh họa cách thêm một Linode khác thông qua Terraform, giả sử bây giờ bạn cũng cần một máy chủ cơ sở dữ liệu riêng. Để thực hiện việc này, bạn có thể tạo một tệp cấu hình Terraform khác cho Linode thứ hai.

Ghi chú: Khi triển khai nhiều Linode với Terraform, hãy nhớ rằng bạn cần phải chỉ định một tên duy nhất cho mỗi Linode.Trong môi trường sản xuất, khóa SSH và mật khẩu gốc của bạn phải là duy nhất cho mỗi tài nguyên. Tuy nhiên, các Linode ví dụ trong hướng dẫn này chia sẻ khóa và mật khẩu gốc.

1.Tạo một tệp khác có tên là linode-terraform-db.tf. Thay thế khóa SSH và mật khẩu gốc của bạn vào nơi được chỉ định. Không xóa linode-terraform-web.tf .

resource "linode_instance" "terraform-db" {
  image = "linode/centos7"
  label = "Terraform-Db-Example"
  group = "Terraform"
  region = "us-south"
  type = "g6-standard-1"
  swap_size = 1024
  authorized_keys = [ "YOUR_PUBLIC_SSH_KEY" ]
  root_pass = "YOUR_ROOT_PASSWORD"
}

Bạn có thể nhận thấy rằng nhà cung cấp Terraform không được chỉ định trong tệp này vì nó nằm trong linode-terraform-web.tf. Terraform tải vào bộ nhớ và nối tất cả các tệp có trong thư mục làm việc có .tfphần mở rộng. Điều này có nghĩa là bạn không cần phải xác định lại nhà cung cấp trong .tfcác tệp mới.

2.Xem lại kế hoạch Terraform:

terraform plan

Terraform biết rằng Terraform-Web-Example Linode của bạn vẫn tồn tại, do đó kế hoạch chỉ hiển thị rằng Terraform-Db-Example Linode sẽ được tạo:

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  + create

Terraform will perform the following actions:

  + linode_instance.terraform-db
      # [...]

Plan: 1 to add, 0 to change, 0 to destroy.

# [...]

3.Áp dụng cấu hình:

terraform apply

4.Kiểm tra Trình quản lý Linode để đảm bảo Linode Terraform-Db-Exampleđã được thêm vào tài khoản của bạn.

Phá hủy máy chủ

Terraform bao gồm lệnh destroy để xóa các máy chủ do Terraform quản lý. Trước khi chạy lệnh destroy, bạn có thể chạy lệnh plan với tùy -destroychọn để xem máy chủ nào sẽ bị xóa:

terraform plan -destroy
# [...]

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  - destroy

Terraform will perform the following actions:

  - linode_instance.terraform-db

  - linode_instance.terraform-web


Plan: 0 to add, 0 to change, 2 to destroy.

# [...]

1.Chạy lệnh destroy để xóa các máy chủ khỏi phần cuối cùng. Xác nhận việc xóa bằng yeskhi được nhắc:

terraform destroy

2.Xác minh rằng Linode đã được xóa trong Linode Manager.

3.Xóa các tập tin cấu hình:

rm *.tf

Cung cấp nhiều máy chủ bằng cách sử dụng biến

Cho đến thời điểm này, quy trình thêm một nút mới vào cơ sở hạ tầng của bạn là tạo một tệp mới và chạy terraform apply. Có một số nhược điểm của cách tiếp cận này:

  • Bạn cần phải sao chép nhiều lần một số giá trị nhất định trong mỗi tệp, như khóa SSH.
  • Nếu bạn muốn thay đổi một số tham số trên nhiều máy chủ, như groupthuộc tính của Linodes, thì bạn cần phải thay đổi từng tệp.

Để giải quyết những vấn đề này, Terraform cho phép bạn khai báo các biến và chèn giá trị của các biến đó vào cấu hình của bạn:

1.Tạo một tệp mới để xác định tên biến và các giá trị biến mặc định tùy chọn. Tệp này có thể có bất kỳ tên nào; đối với ví dụ này, hãy sử dụng variables.tf:

variable "token" {}
variable "authorized_keys" {}
variable "root_pass" {}
variable "region" {
  default = "us-southeast"
}

2.Tạo tệp terraform.tfvarsđể lưu trữ giá trị biến của bạn. Thay thế mã thông báo API, khóa SSH và mật khẩu gốc của bạn vào nơi được chỉ định. Bạn không thể thay đổi tên tệp này sau khi tạo.

token = "YOUR_LINODE_API_TOKEN"
authorized_keys = "YOUR_PUBLIC_SSH_KEY"
root_pass ="YOUR_ROOT_PASSWORD"

3.Tạo một tệp cấu hình mới có tên là linode-terraform-template.tf:

# Linode Provider definition
terraform {
  required_providers {
    linode = {
      source = "linode/linode"
      version = "2.5.2"
    }
  }
}

provider "linode" {
  token = var.token
}

# Example Web Server
resource "linode_instance" "terraform-web" {
        image = "linode/centos7"
        label = "Terraform-Web-Example"
        group = "Terraform"
        region = var.region
        type = "g6-standard-1"
        swap_size = 1024
        authorized_keys = [var.authorized_keys]
        root_pass = var.root_pass
}

# Example Database Server
resource "linode_instance" "terraform-db" {
        image = "linode/ubuntu18.04"
        label = "Terraform-Db-Example"
        group = "Terraform"
        region = var.region
        type = "g6-standard-1"
        swap_size = 1024
        authorized_keys = [var.authorized_keys]
        root_pass = var.root_pass
}

4.Kiểm tra lỗi trong lần triển khai mới của bạn:

terraform plan

5.Áp dụng cấu hình:

terraform apply
  1. Kết quả cuối cùng sẽ giống như trước.

Sửa đổi triển khai trực tiếp

Terraform cho phép bạn thay đổi tên, kích thước hoặc các thuộc tính khác của máy chủ mà không cần phải phá hủy và xây dựng lại. Terraform xử lý việc này thông qua các thay đổi đối với các tệp cấu hình.

Quan trọng: Việc thay đổi kích thước Linode của bạn sẽ buộc máy chủ của bạn phải tắt nguồn và di chuyển đến một máy chủ khác trong cùng một trung tâm dữ liệu. Việc di chuyển đĩa liên quan mất khoảng 1 phút cho mỗi 3-5 gigabyte dữ liệu. Xem hướng dẫn Thay đổi kích thước Linode của chúng tôi để biết thêm thông tin.

1.Sửa đổi linode-terraform-template.tfvà cập nhật typegiá trị g6-standard-4cho terraform-dbtài nguyên.

# [...]

resource "linode_instance" "terraform-db" {
        # [...]
        type = "g6-standard-4"
        # [...]
}

2.Xem lại kế hoạch:

terraform plan
# [...]

An execution plan has been generated and is shown below.
Resource actions are indicated with the following symbols:
  ~ update in-place

Terraform will perform the following actions:

  ~ linode_instance.terraform-db
      type: "g6-standard-1" => "g6-standard-4"


Plan: 0 to add, 1 to change, 0 to destroy.

# [...]

3.Áp dụng những thay đổi của bạn:

terraform apply

4.Xác minh những thay đổi trong Linode Manager.

Mô-đun Terraform

Terraform sử dụng một khái niệm gọi là mô-đun để nhóm các yêu cầu và cấu hình máy chủ chung. Hãy nghĩ về các mô-đun tương tự như các hàm trong ngôn ngữ lập trình.

Ví dụ, giả sử bạn điều hành một công ty web và cần triển khai các cặp máy chủ web và máy chủ cơ sở dữ liệu giống hệt nhau cho các máy khách khác nhau. Để tạo điều kiện thuận lợi cho việc này, bạn có thể tạo một mô-đun Terraform có thể tái sử dụng mô tả cặp máy chủ web và máy chủ cơ sở dữ liệu.

Mô tả của mô-đun cho phép thay thế biến các thuộc tính có liên quan (mật khẩu, khóa, v.v.), giống như trong cấu hình từ phần trước. Sau khi mô-đun được cấu hình, các máy chủ mới có thể được khởi tạo cho mỗi máy khách của bạn bằng cách kết hợp mã mô-đun với một tập hợp các giá trị biến mới.

Cấu trúc mô-đun cơ bản

Cấu trúc mô-đun linh hoạt, do đó bạn có thể sử dụng nhiều tệp Terraform tùy theo nhu cầu để mô tả cơ sở hạ tầng của mình. Ví dụ này chỉ chứa một tệp cấu hình mô tả mã có thể tái sử dụng.

1.Tạo một modules/app-deployment/thư mục để lưu trữ cấu hình mô-đun:

cd ~/terraform
mkdir -p modules/app-deployment

2.Tạo một main.tftập tin cấu hình bên trong modules/app-deployment/:

# Web Server
resource "linode_instance" "terraform-web" {
        image = "linode/ubuntu18.04"
        label = var.webserver_label
        group = "Terraform"
        region = var.region
        type = "g6-standard-1"
        swap_size = 1024
        authorized_keys = var.authorized_keys
        root_pass = var.root_pass
}

# Database Server
resource "linode_instance" "terraform-db" {
        image = "linode/centos7"
        label = var.dbserver_label
        group = "Terraform"
        region = var.region
        type = var.db_type
        swap_size = 1024
        authorized_keys = var.authorized_keys
        root_pass = var.root_pass
}

3.Cấu hình trên tái tạo các ví dụ trước bằng cách sử dụng các biến. Tệp tiếp theo chứa các định nghĩa biến. Gán một giá trị mặc định cho mỗi biến. Giá trị đó được sử dụng nếu bạn không ghi đè khi gọi mô-đun.

Thay thế khóa SSH và mật khẩu gốc của bạn vào nơi chỉ định:

variable "webserver_label" {
    description = "The name for the Web Server"
    default = "default-web"
}

variable "dbserver_label" {
    description = "The name for the Database Server"
    default = "default-db"
}

variable "db_type" {
    description = "The size (plan) for your Database Linode"
    default = "g6-standard-1"
}

variable "region" {
    description = "The default Linode region to deploy the infrastructure"
    default = "us-east"
}

variable "authorized_keys" {
    description = "The Public id_rsa.pub key used for secure SSH connections"
    default = ["default-ssh-public-key"]
}

variable "root_pass" {
    description = "The default root password for the Linode server"
    default = "default-root-password"
}

Làm việc với các mô-đun

Tạo một triển khai cho một máy khách tưởng tượng:

1.Tạo một client1thư mục:

cd ~/terraform
mkdir client1

2.Tạo một main.tftệp cấu hình bên trong client1/sử dụng mô-đun của bạn. Mô-đun được tham chiếu bằng cách cung cấp đường dẫn đến cấu hình của mô-đun. Thay thế mã thông báo API, khóa SSH và mật khẩu gốc của bạn vào nơi được chỉ định:

# Client 1 Infrastructure
terraform {
  required_providers {
    linode = {
      source = "linode/linode"
      version = "2.5.2"
    }
  }
}
provider "linode" {
  token = "YOUR_LINODE_API_TOKEN"
}

module "app-deployment" {
  source = "../modules/app-deployment"

# Variables Specific to this Deployment
region = "us-east"
authorized_keys = [ "YOUR_PUBLIC_SSH_KEY" ]
root_pass ="YOUR_ROOT_PASSWORD"

# Variables Specific to Servers
webserver_label = "client1-web"
dbserver_label = "client1-db"
db_type = "g6-standard-8"
}

3.Cấu trúc tệp cho mô-đun và for của bạn client1bây giờ sẽ trông như sau. Cấu trúc này không bắt buộc bởi Terraform, nhưng nó hữu ích như một ví dụ đơn giản:

client1
└── main.tf
modules
└── app-deployment
&emsp;&emsp;&emsp;&emsp;├── main.tf
&emsp;&emsp;&emsp;&emsp;└── variables.tf

4.Khởi tạo cấu hình Terraform cho máy khách, xem lại kế hoạch và áp dụng:

cd ~/terraform/client1/
terraform init
terraform plan
terraform apply

Sử dụng Linode Object Storage để lưu trữ trạng thái

Tệp dữ liệu trạng thái được Terraform lưu trữ trên một backendterraform.tfstate để ghi nhật ký và theo dõi siêu dữ liệu, ánh xạ tài nguyên vào cấu hình và cải thiện hiệu suất. Theo mặc định, trạng thái được lưu trữ cục bộ trong tệp.

Sử dụng cấu hình bên dưới với backendkhối, bạn có thể thiết lập Terraform để sử dụng Linode Object Storage để lưu trữ trạng thái từ xa. backendKhối phải được lồng vào terraformkhối như đã lưu ý trong tài liệu chính thức về backend của Hashicorp . Trong hướng dẫn này, terraformkhối nằm trong main.tftệp cấu hình.

Lưu ý rằng mô-đun này giả định rằng một thùng lưu trữ đối tượng đã tồn tại trên tài khoản của bạn. Thay thế các giá trị bằng thùng và thông tin khóa của bạn:

# Backend Configuration
backend "s3" {
    bucket = "YOUR-BUCKET-NAME"   # The bucket name created on your account to which your access_key and secret_key can read and write
    key = "tf/tfstate"  # The folder (tf) and object (tfstate) in your bucket where you want to write state to
    region = "us-southeast-1"  # The region where your object storage bucket is at which is the same as the ClusterID Here https://techdocs.akamai.com/cloud-computing/docs/access-buckets-and-files-through-urls#cluster-url-s3-endpoint
    access_key = "OBJ-ACCESS-KEY"  # You can put your value here inline or add it as an environment variable AWS_ACCESS_KEY_ID  see more here https://developer.hashicorp.com/terraform/language/settings/backends/s3#credentials-and-shared-configuration
    secret_key = "OBJ-SECRET-KEY"  # You can put your value here inline or add it as an environment variable AWS_SECRET_ACCESS_KEY see more here https://developer.hashicorp.com/terraform/language/settings/backends/s3#credentials-and-shared-configuration
    skip_region_validation = true  # All of these skip_* arguements are used since our object storage doesn't implement these additional endpoints
    skip_credentials_validation = true
    skip_requesting_account_id = true
    skip_s3_checksum = true
    endpoints = {
      s3 = "https://us-southeast-1.linodeobjects.com"  # The endpoint for the s3 API based on the region your bucket is located https://techdocs.akamai.com/cloud-computing/docs/access-buckets-and-files-through-urls#cluster-url-s3-endpoint
    }
  }

Nguồn: https://www.linode.com/docs/guides/how-to-build-your-infrastructure-using-terraform-and-linode/